0 IFDL=0THENPRINT"[147][144]  WELCOME TO THE GRASSROOTS JUKEBOX..."
1 IFDL=0THENDL=1:POKE808,234:LOAD"BASIC PLAYER",8,1
2 IFDL=1THENDL=2:LOAD"W.BLUEGRASS",8,1
3 IFS%=3THEN550
4 IFS%=4THEN3040
8 POKE53281,1:POKE53280,7
9 NS=8
10 PRINT"[147]"CHR$(142)
20 PRINT"                             "
30 PRINT"           LOADSTAR PRESENTS [144] "
40 PRINT"                             [144] "
50 PRINT"                              "
60 PRINT"[160]"
70 PRINT"[160]"
80 PRINT
90 PRINT
100 PRINT"                                   "
110 PRINT"          GRASSROOTS JUKEBOX       [144] "
120 PRINT"                                   [144] "
130 PRINT"        WRITTEN BY JAMES WEILER    [144] "
140 PRINT"                                   [144] "
150 PRINT"                                    "
160 PRINT
170 PRINT"                           "
180 PRINT"            COPYRIGHT 1987 [144] "
190 PRINT"                           [144] "
200 PRINT"                            "
210 PRINT
220 PRINT"     LOADSTAR IS NOT PUBLIC DOMAIN"
230 PRINT"  PLEASE RESPECT THE AUTHOR'S RIGHTS"
240 PRINT
245 FORX=1TONS:READA$(X),B$(X):NEXT
250 PRINT"             PRESS ANY KEY";
260 PRINT"";
270 POKE198,0:WAIT198,1:POKE198,0
300 PRINT"[147]"
310 PRINT"                                   "
320 PRINT"          GRASSROOTS JUKEBOX       [144] "
330 PRINT"                                   [144] "
340 PRINT"        WRITTEN BY JAMES WEILER    [144] "
350 PRINT"                                   [144] "
360 PRINT"                                    "
370 PRINT
380 PRINT
390 PRINTSPC(5)"USE CURSOR KEYS OR JOYSTICK TO"
392 PRINTSPC(11)"SCROLL HIGHLIGHT."
393 PRINTSPC(5)"[RETURN] OR FIREBUTTON SELECTS."
394 PRINTSPC(11)"PRESS 'Q' TO QUIT"
400 :
410 SE=1
420 GOSUB1000
430 GOSUB2000
440 IFFL=0THEN420
442 IFFL=-1THEN10000
450 :
500 :
510 IFSE=NS+1THEN3000
520 S%=3
530 IFS%=3THENLOADB$(SE),8,1
540 :
550 GOSUB4000
560 GOSUB5000
570 GOTO300
580 :
1000 :
1010 PRINT""
1020 FORX=1TONS/2
1022 IFX=SETHENPRINT"[159]";
1030 PRINTA$(X)SPC(24-LEN(A$(X)));"[146]";
1031 IFX+NS/2=SETHENPRINT"[159]";
1032 PRINTA$(X+NS/2)"[146]"
1040 NEXTX:PRINT"":IFSE=NS+1THENPRINT"[154]";
1050 :
1052 AG$="PLAY ALL"+STR$(NS)+" TUNES."
1055 PRINTSPC(10)AG$"[146]"
1060 RETURN
2000 :
2010 IFPEEK(198)=0ANDPEEK(56320)=127THEN2010
2020 GETA$:J=PEEK(56320)
2022 FL=0:PA=0
2030 IFA$=""ORJ=125THENSE=SE+1
2032 IFA$="[145]"ORJ=126THENSE=SE-1
2034 IFA$=""ORJ=119THENSE=SE+(NS/2)
2036 IFA$="[157]"ORJ=123THENSE=SE-(NS/2)
2040 IFA$=CHR$(13)ORJ=111THENFL=1:GOTO2100
2050 IFA$="Q"ORA$="[209]"THENFL=-1:GOTO2100
2060 IFSE<1THENSE=1
2065 IFSE>NS+1THENSE=NS+1
2070 :
2100 RETURN
3000 :
3010 SE=1:PA=1
3020 GOSUB1000
3030 S%=4:LOADB$(SE),8,1
3040 GOSUB4000
3050 GOSUB5000:IFQU=2THEN3080
3060 SE=SE+1:IFSE=NS+1THEN3080
3070 GOTO3020
3080 GOTO300
3090 :
4000 :
4010 PRINT"                                    [145]"
4020 AG$="NOW PLAYING -- "+A$(SE)
4030 PRINTSPC(20-LEN(AG$)/2)AG$
4040 IFPA=1THENPRINT"      PRESS [SPACE] FOR NEXT SONG"
4042 PRINT"      PRESS [Q] TO RETURN TO MENU"
4045 SYS52222,40960
4050 RETURN
5000 :
5010 IFPEEK(198)=0ANDPEEK(788)<>49THEN5010
5020 SYS52225
5030 GETA$:QU=1
5040 IFA$="Q"ORA$="[209]"THENQU=2
5050 RETURN
10000 PRINT"[147]"
10010 PRINT"  ARE YOU SURE YOU WANT TO QUIT [Y/N]?"
10020 POKE198,0:WAIT198,1:GETA$
10030 IFA$="Y"ORA$="[217]"THEN60000
10040 IFA$="N"ORA$="[206]"THEN300
10050 GOTO10020
10060 :
11000 :
11010 :
11020 DATA ARKANSAS TRAVELER,M.ARKANSAS.TRAV
11030 DATA DOUBLE EAGLE,M.DOUBLE.EAGLE
11040 DATA ROCKY TOP,M.ROCKY.TOP
11050 DATA CRIPPLE CREEK,M.CRIPPLE.CREEK
11060 DATA OLD VIRGINNY,M.OLD.VIRGINNY
11070 DATA CUMBERLAND GAP,M.CUMBERLAND.GAP
11100 DATA LIZA JANE,M.LIZA.JANE
11110 DATA OLD DAN TUCKER,M.OLD.DAN.TUCKER
11999 :
60000 :
60010 POKE808,237
60020 OPEN15,8,15,"R0:HELLO CONNECT=HELLO CONNECT":INPUT#15,ER:CLOSE15
60030 IFER<>63THENPRINT"[147]":END
60040 LOAD"HELLO CONNECT",8